The Beast of Torrack Moor
An interactive fiction by Linda Wright (2007) - the Inform 7 source text
Contents
Previous
Next
Complete text
Abouting is an action out of world. Understand "about" or "info" or "credits" as abouting.
Carry out abouting:
say "[italic type]The Beast of Torrack Moor[roman type] was written by Linda Wright (now Linda Doughty) for the Spectrum in 1988 and was published first by Marlin Games, and then by Zenobi Software. This Inform 7 version was done by Steve Haddon (as an exercise), and is distrubuted with permission of Linda Doughty. Please report any bugs to electrichamlet@gmail.com.[paragraph break]The game is very close to the original. All prose is the original author's, with a few exceptions of extra responses I added for unsuccessful actions. I corrected some minor bugs and grammar errors from the original, and probably introduced a few bugs and typos of my own.[paragraph break]Type HINTS for some general hints.[paragraph break][bold type]Thanks to:[roman type][line break]- Linda Doughty for her kind permission to make this game available.[line break]- Graham Nelson, Emily Short and David Fisher for handy extensions I used.[line break]- Al for doing some much-needed testing.".
Hinting is an action out of world. Understand "help" or "hint" or "hints" as hinting.
Carry out hinting:
say "[bold type]Hints:[roman type][line break]- Ask (person) about (topic) is a useful command in this game[line break]- Since things happen at set times, there are a few instances where you do need to be at the right place at the right time. It may take a few plays through to work out where to be and when![line break]- As such, the game is a little on the unforgiving side in places. For example, you may want to be on a bus by 9.45...[line break]- Examining is very important. There are some key items hidden in innocuous places.[line break]- If you get really stuck, a full solution is available online - Google for it!".
Understand "exam [something]" as examining.
Understand "inv" as taking inventory.
[ Inventory: list carried/worn items separately ]
Instead of taking inventory:
say "You're holding [a list of things carried by the player][if the player wears something]. And you're wearing [a list of things worn by the player][end if]."
[ Knocking]
Knocking on is an action applying to one touchable thing. Understand "knock on [something]" as knocking on. Understand "knock [something]" as knocking on.
Check knocking on:
if noun is not a door, say "I don't see much point in that!" instead.
Carry out knocking on:
say "No-one answers."
[ Throwing ]
Understand the command "throw" as something new.
[ Throwing at ]
Understand "throw [something] at [something]" as throwing it at. Understand "hurl [something] at [something]" as throwing it at. Understand "toss [something] at [something]" as throwing it at.
Carry out throwing something at something:
say "I don't think that's something you should be throwing around."
[ ask someone about known thing ]
Understand "ask [someone] about [any known thing]" as interrogating it about.
Interrogating it about is an action applying to two visible things.
Carry out interrogating someone about something:
say the default response of the noun.
[ ask someone for known thing ]
Understand "ask [someone] for [any known thing]" as requesting it for.
Requesting it for is an action applying to two visible things.
Carry out requesting someone for something:
say the default response of the noun.
[ tell someone about known thing ]
Understand "tell [someone] about [any known thing]" as informing it about.
Informing it about is an action applying to two visible things.
Carry out informing someone about something:
say the default response of the noun.
[talk to someone]
Talking to is an action applying to one visible thing.
Understand "talk to [someone]" as talking to.
Report talking to:
say the default response of the noun.
[ Shout at someone ]
Shouting at is an action applying to one visible thing.
Understand "shout at [someone]" as shouting at.
Understand "shout to [someone]" as shouting at.
Understand "yell at [someone]" as shouting at.
Understand "scream at [someone]" as shouting at.
Shouting to it about is an action applying to two visible things.
Understand "shout to [someone] about [any known thing]" as shouting to it about.
Understand "shout at [someone] about [any known thing]" as shouting to it about.
Understand "tell [someone] loudly about [any known thing]" as shouting to it about.
Understand "yell at [someone] about [any known thing]" as shouting to it about.
Understand "yell to [someone] about [any known thing]" as shouting to it about.
Understand "scream at [someone] about [any known thing]" as shouting to it about.
Understand "scream to [someone] about [any known thing]" as shouting to it about.
Carry out shouting at someone:
say the default response of the noun.
Carry out shouting to someone about something:
say the default response of the noun.
[ Asking what's wrong ]
Asking it what's wrong is an action applying to one visible thing.
Understand "ask [someone] what's wrong" as asking it what's wrong.
Understand "ask [someone] what is wrong" as asking it what's wrong.
Understand "ask [someone] what is the matter" as asking it what's wrong.
Understand "ask [someone] what is the matter" as asking it what's wrong.
Understand "[someone], what's wrong" as asking it what's wrong.
Understand "[someone], what is wrong" as asking it what's wrong.
Understand "[someone], what's the matter" as asking it what's wrong.
Understand "[someone], what is the matter" as asking it what's wrong.
[ Reaching in ]
Reaching in is an action applying to one touchable thing.
Understand "reach in [something]" as reaching in.
Understand "reach into [something]" as reaching in.
Understand "reach inside [something]" as reaching in.
Understand "put arm in [something]" as reaching in.
Understand "put hand in [something]" as reaching in.
Carry out reaching in something:
say "That would achieve little.".
[ Lifting ]
Lifting is an action applying to one touchable thing.
Understand "lift [something]" as lifting.
Carry out lifting something:
say "That would achieve little.".
[ Turning ]
Carry out turning something:
say "That would achieve little.".
[ Breaking ]
Understand the commands "hit" and "break" and "smash" and "wreck" and "shatter" and "attack" as something new.
Breaking is an action applying to one visible thing.
Understand "break [something]" as breaking.
Breaking it with is an action applying to two visible things.
Understand "break [something] with [something]" as breaking it with.
Understand the commands "wreck" and "smash" and "shatter" and "hit" and "attack" as "break".
Carry out breaking something:
say "Violence isn't the answer to this one.".
Carry out breaking something with something:
say "Violence isn't the answer to this one.".
[ Levering ]
Levering it with is an action applying to two touchable things.
Understand "lever [something] with [something]" as levering it with.
Understand "lever [something] open with [something]" as levering it with.
Understand the commands "prise" and "prize" and "force" as "lever".
[ Counting ]
Counting money is an action applying to nothing.
Understand "count money" as counting money.
[Boarding]
Understand the command "board" as "enter".
[Bolting/unbolting]
Bolting is an action applying to one touchable thing.
Understand "bolt [a boltable door]" as bolting.
Understand "lock [a boltable door]" as bolting.
Unbolting is an action applying to one touchable thing.
Understand "unbolt [a boltable door]" as unbolting.
Understand "unlock [a boltable door]" as unbolting.
[Digging]
Digging is an action applying to nothing.
Understand "dig" as digging.
Understand "dig hole" as digging.
Understand "dig with trowel" as digging.
Check digging:
if the player is not carrying the trowel,
say "But, you've noting to dig with." instead.
Carry out digging:
say "Don't bother! It's not worth the effort.".
Digging into is an action applying to one touchable thing.
Understand "dig [something]" as digging into.
Understand "dig in [something]" as digging into.
Understand "dig hole in [something]" as digging into.
Understand "dig [something] with trowel" as digging into.
Check digging into something:
if the player is not carrying the trowel,
say "But, you've noting to dig with." instead.
Carry out digging into something:
say "Don't bother! It's not worth the effort.".
[Putting against]
Putting it against is an action applying to two touchable things.
Understand "put [something] against [something]" as putting it against.
Understand "lean [something] against [something]" as putting it against.
Understand "place [something] against [something]" as putting it against.
Understand "rest [something] against [something]" as putting it against.
Carry out putting something against something:
say "That would achieve little.".
Understand "place [other things] on/onto [something]" as putting it on.
[ Wait until ]
Hanging around until is an action applying to one time.
Check hanging around until:
if the time of day is the time understood, say "It is [time understood] now!" instead;
if the time of day is after the time understood, say "It is too late for that now." instead.
Carry out hanging around until:
while the time of day is before time understood repeatedly follow the turn sequence rules.
Report hanging around until:
say "Time passes..."
Understand "wait until [time]" as hanging around until.
[ Photographing ]
Photographing is an action applying to one visible thing.
Understand "photograph [something]" as photographing.
Understand "photo [something]" as photographing.
Understand "take photograph of [something]" as photographing.
Understand "take photo of [something]" as photographing.
Understand "take picture of [something]" as photographing.
Check photographing:
if the player is not carrying the camera,
say "But you haven't got the camera." instead;
if the film is not in the camera,
say "But... there's no film in the camera!" instead.
Carry out photographing:
say "Click! OK, that's done.".
[ Lighting ]
Firelighting is an action applying to nothing.
Understand "light fire" as firelighting.
Check firelighting:
if the player is not carrying the matches,
say "But... you've no matches!" instead.
Carry out firelighting:
say "That would be dangerous!".
The block burning rule is not listed in any rulebook.
Understand "light [something]" as burning.
Understand "set fire to [something]" as burning.
Understand "ignite [something]" as burning.
A thing is either flammable or nonflammable. A thing is usually nonflammable.
Check burning something:
if the player is not carrying the matches,
say "But... you've no matches!" instead.
Carry out burning something:
if the noun is flammable,
say "That would be dangerous!";
otherwise
say "Sorry, but that won't burn."
[ Eating/ eating with ]
Understand the command "eat" as something new.
Munching is an action applying to one touchable thing.
Understand "eat [something]" as munching.
Carry out munching:
say "That's plainly inedible.".
Eating it with is an action applying to two touchable things.
Understand "eat [something] with [something preferably held]" as eating it with.
Carry out eating something with something:
say "I don't think that would achieve much!".
[ Heating ]
Heating is an action applying to one visible thing.
Understand "heat [something]" as heating.
Understand "cook [something]" as heating.
Understand "heat [something] on fire" as heating.
Understand "cook [something] on fire" as heating.
Understand "heat [something] with fire" as heating.
Understand "cook [something] with fire" as heating.
Check heating something:
if the shepherds-fireplace is not in the location or the shepherds-fire is not in the shepherds-fireplace,
say "No! Or at least, not right now!" instead.
Carry out heating something:
say "That's not something you can cook!".
[ Pouring/Empty ]
Pouring it into is an action applying to two touchable things.
Understand "pour [something] in [something]" as pouring it into.
Understand "pour [something] into [something]" as pouring it into.
Understand the command "empty" as "pour".
Carry out pouring something into something:
say "I don't see the point.".
[ Ringing ]
Ringing is an action applying to one touchable thing.
Understand "ring [something]" as ringing.
Carry out ringing:
say "That's not something you can ring."
[ Borrowing ]
Borrowing is an action applying to one visible thing.
Understand "borrow [something]" as borrowing.
Carry out borrowing:
say "That's not something you can borrow."