The Beast of Torrack Moor
An interactive fiction by Linda Wright (2007) - the Inform 7 source text
Contents
Previous
Next
Complete text
High Street East is a room in Puddlecombe. The printed name is "High Street (East)". High Street East is west of the Green. "Stone buildings to the north and south have small notices stuck to the inside of their relative doors, whist the street itself leads east and west. The wind, meanwhile, howls about your body, and ominous grey clouds scurry overhead."
The Estate Agents is a room in Puddlecombe. "The establishment of 'Connum and Fleesum' may be small, but it resembles the majority of Estate Agents, being lavishly carpeted and having expensive-looking desks, behind one of which sits a smartly-dressed youth, whilst photographs of luxury houses line the walls."
The Stores is a room in Puddlecombe. "This quaint shop sells various goodies at highly inflated prices, which is why most of the villagers shop elsewhere. A parrot, sitting on his perch by the door, squawks 'Allo, allo' at fairly regular intervals, whilst the owner, Lily White, eyes you with obvious curiosity."
High Street West is a room with printed name "High Street (West)". High Street West is west of High Street East. "The High Street fizzles out to the west as it joins the road which leads to Lowsea, whilst a narrow dusty lane branches off to the north. A rather plain stone building to the south has a plaque on the door which, considering the drabness of the house, is quite attractively panelled."
Quarry Lane is north of High Street West. "High hedges flank either side of this dusty lane, which appears to be little used. A sign half-buried in the foliage points north to [bold type]THE OLD QUARRY[roman type] whilst the High Street Lies to the south."
The Old Quarry is north of Quarry Lane. "Steep rockfaces, which once were blasted out of the hillside but now play host to a variety of shrubs and wild-life, surround you, whilst a small semi-derelict shack stands to the west and the lane lies to the south[if the shack-window is broken]. The window of the shack is broken[end if]."
The Shack is a room. "Inside this corrugated hut you smugly notice the broken window and open door whilst various insects scurry around the earthen floor."
Road-room is west of High Street West. The printed name of road-room is "A Road". "This long east-west road leads monotonously towards the town of Lowsea in one direction and to the village of Puddlecombe-by-the-Moor in the other, and is not recommended as a scenic route, a long diversion or even a short stroll..." Road-room is west of road-room.
Vet's Waiting Room is a room in Puddlecombe. "A row of uncomfortable-looking chairs have been placed a long one of the white-washed walls of this room, whilst a few posters and a pleasant aquarium do their best to cheer the place up. Doors lead north and south, whilst a receptionist sits staring at you from behind her desk."
The Surgery is a room in Puddlecombe, south of Vet's Waiting Room and inside of Vet's Waiting Room. "This clinical room is kitted out with all the necessary items required by a practising vet, including a large white table on which most animals are examined. A painting of panthers hangs by the northern door, whilst Mr Andy Bittern scrutinises you in a most disconcerting way."
[ HIGH STREET EAST ]
The shop notices are scenery in High Street East. Understand "notice" as the shop notices. The description is "The notice on the Estate Agent's door reads [bold type]Open 9-5[roman type], whilst that on the Stores reads the same, with the addition of [bold type]Closed for lunch 1-2[roman type]."
The door of the estate agents is a shop door in High Street East. It is scenery. Understand "agents'" as the door of the estate agents. The door of the estate agents is north of high street east and south of the estate agents. The door of the estate agents is open.
The door of the stores is a shop door in High Street East. It is scenery. The door of the stores is south of high street east and north of the stores. The door of the stores is open.
[ ESTATE AGENTS ]
The carpet is scenery in the estate agents.
The photographs of houses are scenery in the estate agents.
The expensive desks are scenery in the estate agents. The description is "Highly polished, with a sign reading [bold type]IAN CONNUM[roman type] placed upon it."
The youth is a man in the Estate Agents. The youth is scenery. Understand "Estate", "Agent", "Ian", "Connum" as the youth. The description is "A flowery-speaking individual whose only interest lies in selling houses and making money as quickly as possible!"
The default answer of the youth is "He looks at you with a vaguely bored smile upon his face, and utters a few incomprehensible remarks before turning away. Obviously not one of life's most helpful characters!"
The yale key is a key.
The details are a thing. The details are proper-named. The printed name is "the details (of Ivy Cottage)". The description is "The house details of Ivy Cottage go to great lengths to stress the desirability of this small property, which, although in need of some modernisation, has a compact kitchen with fine gardens, and outbuilding, bedroom etc. Really, at the price of only £180,000 you'd be daft not to buy it!"
Ivy Cottage is a known thing. [Used also as scenery in overgrown garden]
Housing is a known thing. Understand "property" and "houses" as housing.
Instead of interrogating youth about housing:
try interrogating youth about Ivy Cottage.
Instead of interrogating youth about Ivy Cottage for the first time:
say "Suddenly, the estate agent takes a keen interest in you, jumps up and looks through the junk on his desk before handing you some house details and a key, saying 'This is a nice little property, secluded, with great potential for someone like you... Ivy Cottage, it's called, situated between Church Lane and Moor Lane. It's empty now, so you can let yourself in, but please return the key when you've finished.'";
now the yale key is found;
move the yale key to the location;
try taking the yale key;
move the details to the location;
try taking the details.
Instead of giving the yale key to youth:
say "With a shrug, Mr Connum takes the key as you explain that you're not interested in purchasing the cottage, then he insists on putting your name and address on his books so that he can flood you with unwanted mailshots for the next six months... oh, well! At least you found something of use in the cottage... no? Whoops! Too late, now!";
remove the yale key from play.
Instead of exiting in Estate Agents:
try going south.
[ THE STORES ]
The 35mm film is a purchasable in the stores. It is pocketable. The description is "A black and white 35mm film." The cost of the film is £3.00.
The can is a purchasable in the stores. Understand "baked" and "beans" as the can. The description is "[if the baked beans are part of the can]Full of juicy baked beans![otherwise]It's empty.[end if]". The cost of the can is £0.50. The can can be open or closed. The can is closed. The printed name of the can is "[if the baked beans are not part of the can]empty [end if]can[if the can is open] (open)[end if]".
Some baked beans are part of the can. The baked beans can be hot or cold. The baked beans are cold.
[ Distinguish between the player referring to the beans on their own and the beans in the can. ]
Does the player mean doing anything to the baked beans when the can is closed: it is unlikely.
Does the player mean doing anything to the baked beans when the baked beans are not part of the can: it is likely.
Rule for clarifying the parser's choice of the can: stop.
Rule for clarifying the parser's choice of the baked beans: stop.
[ The tin opener is required to open the can ]
Instead of opening the can:
if the tin opener is carried by the player,
try unlocking the can with the tin opener;
otherwise
say "You don't have the correct implement!".
Instead of unlocking the can with the tin opener:
if the can is open begin;
say "The can is already open.";
otherwise;
now the can is open;
say "OK, that's done.";
end if.
[ The beans are awkward - the player must eat them, but not pick them up separately from the can itself ]
Instead of doing anything to the baked beans when the can is closed:
say "You'll have to open the can first!".
Instead of taking the baked beans when the can is open:
say "Yuck! No thanks!".
[ Separate "munching" verb, so as to avoid the eating verb trying to automatically take the beans from the can ]
Instead of munching the baked beans:
if the baked beans are cold begin;
say "Yuck! No thanks! They're cold!";
otherwise if the player is not carrying the plastic teaspoon;
say "Ouch! Your fingers are scorched by the hot beans... you could really do with a spoon or fork, you know!";
otherwise;
say "Using the spoon, you greedily eat the hot beans, and feel much better for it!";
record "eating a hot meal" as achieved;
change the food index to 1;
remove the baked beans from play;
end if.
Does the player mean munching the baked beans: it is likely.
Instead of eating the baked beans with the plastic teaspoon:
try munching the baked beans.
[ The player can heat the beans in the pan (although it's optional, strangely) ]
Instead of inserting the baked beans into the battered pan when the can is open and the baked beans are part of the can:
move the baked beans to the pan;
say "OK, that's done.";
Instead of pouring the baked beans into the battered pan:
try inserting the baked beans into the battered pan.
Instead of pouring the can into the battered pan when the beans are part of the can:
try inserting the baked beans into the battered pan.
Does the player mean heating the baked beans when the can is open: it is very likely.
[ The beans can only be heated in the shepherd's hut when the fire is lit ]
Instead of heating the baked beans when the can is open:
if the shepherds-fire is in the shepherds-fireplace begin;
say "OK, that's done.";
now the baked beans are hot;
otherwise;
say "That would be difficult...";
end if.
Instead of heating the battered pan:
if the baked beans are in the pan,
try heating the baked beans;
otherwise
say "I don't see the point!".
[ The torch remains on for a certain number of turns ]
The torch is purchasable in the stores. Understand "flashlight" as the torch. The torch can be lit or unlit. The torch is unlit. The description is "Battery-operated, and intact with batteries, bulb, case, switch etc[if the torch is lit]. It is lit[end if]." The cost of the torch is £1.00. The printed name is "[if the torch is lit]lit [end if]torch". The torch has a number called battery life. The battery life of the torch is 45.
Every turn when the torch is lit:
change the battery life of the torch to the battery life of the torch minus one;
if the battery life of the torch is 0 begin;
now the torch is unlit;
if the torch is carried by the player or the torch is in the location,
say "The batteries of the torch have just worn themselves out, and the torch light flickers then goes out altogether...";
end if.
Instead of switching on the torch:
if the torch is lit begin;
say "The torch is already switched on.";
otherwise;
if the battery life of the torch is 0 begin;
say "You try, but the batteries are dead.";
otherwise;
now the torch is lit;
say "OK, that's done.";
end if;
end if.
The batteries are part of the torch. The bulb is part of the torch. The case is part of the torch. The switch is part of the torch.
[ Lily and the parrot are somewhat one-dimensional characters... ]
The parrot is scenery in the stores. Instead of talking to the parrot: say "Putting its head on one side, it squawks 'Allo, allo'."
Lily White is a villager woman in the stores. Lily White is scenery. The description is "Very ordinary!"
Instead of talking to Lily: say "She looks at you strangely, but says nothing."
Instead of taking a purchasable in the stores:
if the noun is not bought,
say "You suddenly find out that Polly can say something other than 'Allo', for it suddenly squawks 'Thief, thief!' Red-faced, you decide that you'd better pay first and hastily drop [the noun].";
otherwise
continue the action.
Instead of exiting in the stores:
try going north.
[ HIGH STREET WEST ]
The road is scenery in High Street West.
[ The stone building is the vet's ]
The stone building is scenery in High Street West. Understand "house" as the stone building.
The vet-plaque is scenery in High Street West. The printed name is "plaque". Understand "plaque" as the vet-plaque. The description is "Reads: [bold type]MR A. BITTERN, VETERINARY SURGEON.[roman type] [italic type]OPENING HOURS 10am to 5pm[roman type]."
The door of the stone building is a door and scenery. It is south of High Street West and inside of High Street West and north of Vet's Waiting Room and outside of Vet's Waiting Room. It is open and unlocked.
[ QUARRY LANE ]
Some pebbles are a thing in quarry lane. They are pocketable. The description is "Round, small and brown."
The sign is scenery in quarry lane.
The dusty lane is scenery in quarry lane.
[ OLD QUARRY ]
The steep rockfaces are scenery in the old quarry.
The hillside is scenery in the old quarry.
The shrubs are scenery in the old quarry.
The wildlife is scenery in the old quarry. Understand "wild-life" as the wildlife.
The shack-in-the-quarry is scenery in the old quarry with printed name "shack". Understand "shack" as the shack-in-the-quarry. The description is "Made of corrugated iron, it has a door, a small window and a roof as well as four walls, and was possibly once used as a storage shed."
The shack-walls are scenery in old quarry. Understand "walls" as the shack-walls.
The shack-roof is scenery in old quarry. Understand "roof" as the shack-roof.
The latch is scenery in old quarry.
[ The shack door doesn't have a key, so it's a "private" door ]
The shack-door is a private door. Understand "door" as the shack-door. The printed name is "door". The shack-door is scenery. It is west of the old quarry and inside of the old quarry and east of the shack and outside of the shack. It is closed and locked. The description is "Locked, with a standard yale-type lock that has a latch on the other side."
The shack-window is scenery in old quarry. Understand "window" as the shack-window. The printed name is "window". The shack-window can be broken or not broken. It is not broken. The description is "[if the shack-window is broken]The window is broken. Peering through it[otherwise]Peering through the window[end if], you notice the latch on the door as well as being able to make out a chest in one corner of the shack."
[ The player breaks the shack window if he's carrying the brick ]
Instead of breaking the shack-window with something when the shack-window is not broken:
if the second noun is the brick begin;
say "The brick smashes through the window, which is now well and truly broken.";
now the shack-window is broken;
move the brick to the shack;
record "breaking" as achieved;
otherwise;
say "Unfortunately, that won't do it...";
end if.
Instead of breaking the shack-window:
if the player is carrying the brick,
try breaking the shack-window with the brick;
otherwise
say "Unfortunately, nothing that you are currently holding will do that...".
[ Throw brick at window works too... ]
Instead of throwing the brick at the shack-window when the shack-window is not broken:
try breaking the shack-window with the brick.
[ The player needs gloves to unbolt the door from outside ]
Instead of opening the shack-door when the shack-door is locked and the shack-window is broken:
if the player is not wearing the gloves begin;
say "You start to put your hand through the broken window, but decide against it, as you realise that you're in grave danger of badly cutting your hand.";
otherwise;
say "Putting your gloved hand through the broken window, you turn the latch and the door swings open.";
now the shack-door is unlocked;
now the shack-door is open;
record "entering" as achieved;
end if.
Instead of reaching in the shack-window:
if the shack-window is broken,
try opening the shack-door;
otherwise
say "The window prevents that!".
Instead of lifting the latch:
try reaching in the shack-window.
Instead of turning the latch:
try reaching in the shack-window.
[ THE SHACK ]
Shack-window-inside is scenery in the shack. The printed name is "window". Understand "window" as shack-window-inside.
The insects are scenery in the shack.
The earthen floor is scenery in the shack.
A huge chest is an openable closed container in the shack. It is not portable. The description is "Fixed to the floor, it's not portable and is currently [if the chest is open]open[otherwise]closed[end if]."
A hammer is a thing in the chest. The description is "A useful implement with a small hammer head and a metal claw."
The leather pouch is a thing in the chest. Understand "gunpowder" as the pouch. The description is "Contains a reasonable quantity of gunpowder[if the wick is part of the pouch]. Tied to the pouch is a long wick[end if]."
[ VET'S WAITING ROOM ]
The chairs are scenery in vet's waiting room.
The white-washed walls are scenery in vet's waiting room.
The posters are scenery in vet's waiting room. The description is "Depict various wildlife and animal protection societies, whilst others are just pretty pictures of pets, like cats, dogs, a tortoise and so on."
The aquarium is scenery in vet's waiting room.
The receptionist is a woman in vet's waiting room. The receptionist is scenery. The description is "Very ordinary!"
The default answer of the receptionist is "Unfortunately, she seems to be too busy to take any notice of you at all - either that, or she's being extremely rude! Whatever the reason, she doesn't answer."
Instead of going south in the vet's waiting room:
if the tortoise is not held by the player and the tortoise is not on the large white table begin;
say "Noticing you move towards the southern door, the Receptionist stops you, saying 'Sorry! You can't enter unless you have an animal in need of attention!' and looks at you so sternly that you don't have the nerve to disobey!";
otherwise;
send the player to the surgery;
record "gaining access to the vet's surgery" as achieved;
end if.
Instead of going inside in the vet's waiting room:
try going south.
[ THE SURGERY ]
The vet is in the surgery. The vet is scenery. Understand "Mr" and "Andy" and "Bittern" as the Vet. The description of the Vet is "Very ordinary!". The default answer of the vet is "I'm afraid he's too deep in thought to answer!".
The large white table is scenery and a supporter in the surgery. The description is "Has a tortoise on it!"
[ I think the player can remain here for ever if they choose, as the vet examines the tortoise into perpetuity... ]
After looking in the Surgery for the first time:
say "Seeing the tortoise, Mr Bittern exclaims 'Ah! I see you've found Winston! He strayed from my place weeks ago! Thanks for returning him to me!' and promptly takes the tortoise from you, placing him on the table and giving him a quick examination.";
now the tortoise is on the white table.
Instead of taking the tortoise when in the surgery:
say "No! Someone might object!".
The painting of panthers is scenery in the surgery. Understand "picture" as the painting of panthers. The painting of panthers is known.
[ Two ways to trigger his response - asking him about panthers, and examining the picture ]
After examining the painting of panthers for the first time:
try interrogating the vet about the painting of panthers.
Instead of informing the vet about the dead sheep:
try interrogating the vet about the dead sheep.