The Beast of Torrack Moor
An interactive fiction by Linda Wright (2007) - the Inform 7 source text
Contents
Previous
Next
Complete text
Church Lane is a room in Puddlecombe, southeast of the Green. "This narrow lane leads in a southeasterly direction towards the church, whilst gates to the south and southwest lead into gardens. A poster is stuck onto the wall of the Church Hall to the east, whilst the path snakes its way northeastwards between two hedges."
Moor Lane West is a windy room in Puddlecombe. The printed name is "Moor Lane (West)". Moor Lane West is northeast of the Green. "Little more than a stony track, this lane leads east, with the Green to the southwest, whilst a large corrugated hut, with a sign reading [italic type]SCOUT HUT[roman type] nailed above the door, lies to the north."
Moor Lane East is a room in Puddlecombe. The printed name is "Moor Lane (East)". Moor Lane East is east of Moor Lane West. "The lane ends to the east in a muddy farmyard, and a small house nestles behind some scrubby bushes to the southeast. To the south you notice a path which leads through a gap in the hedge whilst, on the opposite side of the lane, you can see the garden of a large house."
The Small Path is a room in Puddlecombe. The small path is south of Moor Lane East and northeast of Church Lane. The Small Path has printed name "A Path". "Twisting its way between two high hedges, the path leads north to Moor Lane and southwest to Church Lane[if the house-gate is found]. You also notice a gate to the southeast[end if]."
Pretty Garden is a room in Puddlecombe. Pretty Garden is south of Church Lane. The printed name of Pretty Garden is "A Pretty Garden". "Lavender, heather and various shrubs line the path of this Olde English style garden, whilst roses climb around the green door to the south, almost hiding the large bell set into the door-frame. A shiny plaque on the wall reads [italic type]MYRTLE COTTAGE[roman type], and a thrush eyes you from the safety of a nearby tree."
Myrtle Cottage is a room in Puddlecombe. North of Myrtle Cottage is Pretty Garden. Outside of Myrtle Cottage is Pretty Garden. "The front room of Myrtle Cottage is full of polished furniture and various knick-knacks that would bring a gleam to the eye of any antiques dealer. A log fire blazes happily in the red brick fireplace, whilst a thick curtain hanging by the door ensures that no draughts whistle around the occupants[apostrophe] feet."
Attractive Garden is a room in Puddlecombe. Attractive garden is north of moor lane east. The printed name is "An Attractive Garden". "Large shrubs and well-weeded flower beds surround this front garden, whilst a path wends its way northeastwards around the large brick house that stands to the north. An impressive oak-panelled door is firmly shut, and a a plaque next to it reads [italic type]Dr. A. M. SAWLY[roman type]."
Side of House is a room in Puddlecombe, northeast of attractive garden. "The side garden consists of a large lawn with various bushes neatly arranged around the perimeter, whilst a conservatory juts out from the side of the house, its glass door closed to retain the heat required for the numerous pot plants growing inside. You also observe the doctor inside the conservatory."
The Vicarage is a room in Puddlecombe. North of Vicarage is The Vicarage Garden. Outside of Vicarage is the Vicarage Garden. "The hall, although uninteresting in its decor, exudes an air of homeliness, and is a complete contrast to the garden, being strewn with various items of junk, whilst water colour paintings of a church, local landscapes and so on hang on the walls."
The Vicarage Garden is a room in Puddlecombe, southwest of Church Lane. "Sheltered by high hedges from the wind, this garden has some very neat borders and an immaculately mown lawn, whilst the Vicarage, a pebbledash building with a plain door, lies to the south."
The Church Hall is a room in Puddlecombe. "Crowded with old dears pushing and shoving in order to get the best of the bargains, the hall has various stalls strategically placed around the perimeter, and you quickly observe that the only exit leads west towards the lane and safety."
The Scout Hut is a room in Puddlecombe. "A standard hut-type building with a grubby wooden floor and scout emblems, posters and the like adorning the walls, it fulfills its main purpose while not pandering to those scouts who might prefer luxury to the rigours of knot typing and camping."
The Ranger's House is a room in Puddlecombe. Northwest of ranger's house is Moor Lane East. Outside of ranger's house is Moor Lane East. "A small orderly place, this is an ideal house for the ranger, being extremely uninteresting, very banal and totally drab. However, colourful posters on the wall go some way to brightening things up, as does the pile of leaflets on the table and a notice pinned on the door."
[ BACKDROPS ]
The lawn is a backdrop. It is in vicarage garden and side of house.
The hedges are a backdrop. The hedges are in Small Path, Vicarage Garden, Quarry Lane. Understand "hedge" as the hedges.
A thing called the path is a backdrop. The path is in Small Path, Church Lane, Pretty Garden, Attractive Garden, Outside-Church.
A thing called the church is a backdrop in Puddlecombe. Understand "St", "Peter" as the church.
[ We can even examine the clock from indoors...ah well ]
The clock is a backdrop in Puddlecombe.
The shrubs are a backdrop. The shrubs are in attractive garden and pretty garden.
The house-plaque is a backdrop. The house-plaque is in attractive garden and pretty garden. The printed name of the house-plaque is "plaque". Understand "plaque" as the house-plaque.
[ SMALL PATH ]
The house-gate is a hidden object. It is scenery. The printed name is "gate". Understand "gate" as the house-gate.
Check opening the house-gate:
say "The gate opens easily, and closes again quietly." instead.
Check closing the house-gate:
say "It's closed." instead.
Instead of examining the hedges in small path:
if the house-gate is not found begin;
say "Ah! You discover a gate to the southeast.";
now the house-gate is found;
now the house-gate is in small path;
now the overgrown garden is mapped southeast of small path;
now the small path is mapped northwest of overgrown garden;
record "discovering a hidden gate" as achieved;
otherwise;
say "You search carefully, but find nothing new.";
end if.
[ CHURCH LANE]
The Church-Hall-Object is scenery in Church Lane. The printed name is "Church Hall". Understand "church", "hall" as the Church-Hall-Object.
The gates and the hedges are scenery in Church Lane.
The poster is scenery in Church Lane. The description is "[italic type]JUMBLE SALE: 2pm today[roman type]."
The Church Hall door is a door and scenery in Church Lane. It is closed and locked. It is east of Church Lane and inside of Church Lane and west of the Church Hall and outside of the Church Hall.
[ MOOR LANE WEST/EAST ]
The Scout-hut-object is scenery in Moor Lane West. The printed name is "Scout Hut". Understand "scout", "hut", "corrugated" as the Scout-hut-object.
Does the player mean doing anything to the Scout-hut-object: it is very likely.
The hut door is a door and scenery. The hut door is north of Moor Lane West and inside of Moor Lane West and south of the Scout Hut and outside of the Scout Hut. The hut door is closed, lockable and locked. The iron key unlocks the hut door.
[ The general rule for doors - if you exit to a windy room, they slam shut ]
After looking in a windy room when an open public door (called the portal) is in the location:
say "The door, caught by the wind, slams shut.";
now the portal is closed.
The garden in the distance is scenery in Moor Lane East. The garden in the distance has printed name "garden".
The large house is scenery in Moor Lane East.
The small house is scenery in Moor Lane East.
The gap in the hedge is scenery in Moor Lane East.
The scrubby bushes are scenery in Moor Lane East.
The moor lane east path is scenery in Moor Lane East. The moor lane east path has printed name "path".
The farm yard is scenery in Moor Lane East. Understand "farmyard" as the farm yard.
[ A PRETTY GARDEN ]
The lavender is scenery in pretty garden.
The heather is scenery in pretty garden.
The roses are scenery in pretty garden.
The large bell is scenery in pretty garden.
The door frame is scenery in pretty garden.
The thrush is scenery in pretty garden.
The tree is scenery in pretty garden.
Instead of ringing the large bell:
try knocking on the green door.
Instead of pushing the large bell:
try knocking on the green door.
The green door is a door in pretty garden. It is private. The green door is scenery. The green door is south of pretty garden and inside of pretty garden.
[ Rudely invading - see further in the story; just displays a message and prevents the player from entering a person's house unannounced ]
Opening the green door is rudely invading.
Does the player mean doing anything to the green door: it is very likely.
Instead of knocking on the green door when Miss Myrtle is in Myrtle Cottage and the darkness index is 0:
say "After a while, you hear footsteps and the door opens. Quickly, you explain who you are and you're invited in...";
move player to Myrtle Cottage.
[ MYRTLE COTTAGE ]
The polished furniture is scenery in Myrtle Cottage.
The knick-knacks are scenery in Myrtle Cottage. Understand "knick", "knacks" as the knick-knacks.
The log fire is scenery in Myrtle Cottage. The description is "Hot!".
The red-brick fireplace is scenery in Myrtle Cottage. Understand "red", "brick" as the red-brick fireplace.
The curtain is scenery in Myrtle Cottage.
Miss Myrtle is a villager woman in Myrtle Cottage. "Miss Myrtle is here." The description is "A sweet little old lady, with grey hair and blue eyes." Understand "Rose" as Miss Myrtle.
The default answer of Miss Myrtle is "She smiles, but says nothing."
Instead of interrogating Miss Myrtle about the letter:
try interrogating Miss Myrtle about the beast.
[ Miss Myrtle starts looking for you after you buy a raffle ticket ]
Miss Myrtle can be normal or seeking a raffle winner. Miss Myrtle is normal.
[ ATTRACTIVE GARDEN ]
The large brick house is a backdrop. The large brick house is in attractive garden and side of house.
The shrubs are scenery in attractive garden.
The flower beds are scenery in attractive garden.
The oak-panelled door is a closed private door and scenery. The oak-panelled door is north of attractive garden and inside of attractive garden.
[ Stop the player wandering in ]
Opening the oak-panelled door is rudely invading.
[ SIDE OF HOUSE ]
The bushes are scenery in side of house.
The conservatory-object is scenery in side of house. The printed name is "conservatory". Understand "conservatory" as the conservatory-object.
The pot plants are scenery in side of house.
The glass door is a private door. The glass door is scenery and closed. It is north of side of house and inside of side of house.
Opening the glass door is rudely invading.
Instead of knocking on the glass door when the doctor is in the conservatory:
say "Knocking on the door, you wait patiently for the doctor to answer. However, he doesn't seem to have heard you..."
[ We can see the doctor through the glass of the conservatory ]
The doctor is in the Conservatory. The description of the doctor is "[if the doctor is in the conservatory]Busy with his plants, he has his back to you...[otherwise]Very ordinary![end if]".
After deciding the scope of the player when the location is side of house and the doctor is in the conservatory:
place the doctor in scope.
Instead of throwing pebbles at something:
if the second noun is the conservatory-object and the doctor is in the conservatory begin;
say "The pebbles clatter noisily on the glass of the conservatory. Although the doctor hasn't heard them, he sees them falling, turns and looks up... spying you, he comes out, shouting 'Can I help you?'";
move doctor to side of house;
otherwise;
say "They clatter noisily on the ground.";
end if;
move pebbles to location.
Instead of throwing pebbles at the glass door:
try throwing pebbles at the conservatory-object.
Instead of throwing pebbles at the doctor:
try throwing the pebbles at the conservatory-object.
Instead of shouting at doctor when the doctor is in the location:
say "With a puzzled look, the doctor just shrugs."
[ Once you get the doctor's attention, he rushes off, and shortly afterwards an ambulance rushes towards the twitcher, then back again a few moves later. The player can not actually get to the ditch in time to see anything happen, so that's not implemented ]
To say the ambulance heading (way - a direction):
say "You hear an ambulance siren[if the location is Moor Lane East or the location is Moor Lane West or the location is Farmyard or the location is field]... then jump out of the way as an ambulance rushes past, heading [way].[otherwise]...[end if]"
At the time when the ambulance heads east:
say the ambulance heading east.
At the time when the ambulance heads west:
say the ambulance heading west.
Instead of shouting to doctor about bird watcher when the doctor is in the location:
say "The doctor, understanding you at last, gets you to tell him all you know, then goes back in grabs his bag, phones for an ambulance and rushes off towards the farm...";
remove the doctor from play;
remove the bird watcher from play;
move the camera to the ditch;
record "communicating with the doctor" as achieved;
The ambulance heads east in two minutes from now;
The ambulance heads west in four minutes from now.
[ CONSERVATORY]
[ Dummy room - the player can't enter it ]
Conservatory is a room.
The default answer of the doctor is "He can't hear you, I'm afraid!"
[ VICARAGE GARDEN ]
The borders are scenery in vicarage garden.
The vicarage-object is scenery in vicarage garden. The printed name is "Vicarage". Understand "vicarage","building","pebbledash" as the vicarage.
The plain door is a private door and scenery. The plain door is closed. The plain door is south of the vicarage garden and inside of vicarage garden.
[ "Rudely invading" stops the player opening doors of the various cottages/houses ]
Opening the plain door is rudely invading.
Instead of knocking on the plain door when the Reverend is in the Vicarage and the darkness index is 0:
say "After a while, you hear footsteps and the door opens. [if the vicarage is not visited]Quickly, you explain who you are and you're invited in[otherwise]With a smile, the Reverend says 'Ah! Hello again,' and asks you in[end if]...";
move player to the vicarage.
[ THE VICARAGE ]
The decor is scenery in the vicarage.
The junk is scenery in the vicarage.
The watercolour paintings are scenery in the vicarage.
The painting of a church is scenery in the vicarage.
The local landscapes are scenery in the vicarage.
The iron key is a key.
[ The Reverend ]
The Reverend is a villager man in the Vicarage. "The Reverend S. Ermon is here". Understand "Ermon" as the Reverend. The printed name is "Reverend S. Ermon". The Reverend is proper-named. The description is "Tall, thin and bespectacled."
The default answer of the reverend is "I'm afraid he's too deep in thought to answer!"
Interrogating the Reverend about something for the first time is reminding the reverend.
[ The first time you talk to Ermon, he gives you the iron key ]
Before reminding the reverend:
if the iron key is not found begin;
say "In a world of his own, the Reverend asks: 'Could you do me a favour? I left a box of books for the Jumble Sale in the Scout Hut... I haven't got time to get them, but I'd be grateful if you could get them for me...' and, before you have time to say anything, he gives you a key as he mutters 'Thanks ever so...'!".
move the iron key to location;
now the iron key is found;
try taking the iron key instead;
end if.
The sturdy shoes are a thing. The sturdy shoes are wearable. The description is "Ideal for wearing on long walks, they're your size and don't seem to be needed by anyone else at the moment."
Instead of wearing the sturdy shoes when the player is wearing the thin trainers:
say "Nope! Not while you're still wearing the thin trainers!".
Instead of wearing the thin trainers when the player is wearing the sturdy shoes:
say "Nope! Not while you're still wearing the sturdy shoes!".
Instead of giving the box to the reverend:
say "Taking the box, the Reverend thanks you, then says 'I was going to put these into the Jumble, but I thought that you might like them... they look as though they're your size...' and hands you a pair of shoes as you mumble a 'Thanks... great!'";
remove the box from play;
now the sturdy shoes are in the location;
try taking the sturdy shoes;
record "being awarded some sturdy shoes" as achieved.
Before giving the old books to the reverend:
try giving the box to the reverend instead.
[ The reverend will tell you that Miss Myrtle is looking for you, if she is! ]
A reminder is a kind of thing. A reminder is either flagged or unflagged. A reminder is usually unflagged. The Reverend has a reminder called raffle news.
Every turn when the player is in the location of the Reverend:
if Miss Myrtle is seeking a raffle winner and raffle news of the Reverend is unflagged and the notice-board is amended and Miss Myrtle is not in the location begin;
say "Suddenly, the reverend says 'Miss Myrtle wanted you... seems you won the raffle!', and smiles.";
now raffle news of the reverend is flagged;
end if.
[ CHURCH HALL]
The stalls are scenery in the Church Hall. The description is "Typical jumble, and you decide that there's nothing worth buying at all." Understand "jumble" as the stalls.
[ Ensure that Miss Myrtle only tries to get you to buy a ticket once! ]
Miss Myrtle is either sales pitched or not sales pitched. Miss Myrtle is not sales pitched.
To say Miss Myrtle's sales pitch:
say "Smiling, Rose Myrtle says 'Buy a raffle ticket and win a rug! Only 10p, and it's all for a good cause!'";
now Miss Myrtle is sales pitched.
Every turn in the Church Hall when Miss Myrtle is not sales pitched:
if the player has been in the Church Hall for 4 turns,
say Miss Myrtle's sales pitch.
Instead of talking to Miss Myrtle in the Church Hall when Miss Myrtle is not sales pitched:
say Miss Myrtle's sales pitch.
The raffle ticket is a hidden object. It is pocketable. The description is "Very small, with the number 211 printed on it."
Instead of buying the raffle ticket when the raffle ticket is found:
say "You've already bought a ticket!"
[ To overcome ambiguities when the player is carrying the pink ticket, and tries to buy a raffle ticket ]
Does the player mean buying the pink ticket: it is very unlikely.
The raffle ticket is carried by Miss Myrtle.
Instead of doing anything with the not found raffle ticket:
say "You'll need to buy one first!".
Before buying the raffle ticket in the Church Hall:
if the raffle ticket is not found begin;
calculate funds;
if total money is less than the £0.10 begin;
say "You don't have enough money!";
otherwise;
spend £0.10;
say "Miss Myrtle smiles, thanks you for your support, writes your name on her list and gives you a ticket.";
move raffle ticket to location;
now the raffle ticket is found;
try taking the raffle ticket;
end if;
otherwise;
say "No - that isn't necessary.";
end if;
stop the action.
The large rug is a hidden object. The description is "The home-knitted multi-coloured variety, it looks as though it would keep any occupant of a bed it was on very warm and snug, although it's not exactly the sort you fancy having in your own home. Still, you could always donate it to Oxfam when you return to Lowsea!".
[ Miss Myrtle wanders around looking for the player, and gives him a rug if they meet ]
Every turn when the player is in the location of Miss Myrtle:
if Miss Myrtle is seeking a raffle winner begin;
say "Suddenly, Miss Myrtle smiles and says 'Ah! Just the person I wanted to see! You won this in the raffle!' before thrusting a rug into your hand.";
now Miss Myrtle is normal;
move the rug to the location;
now the rug is found;
try taking the rug;
record "winning a lovely rug" as achieved;
end if.
[ SCOUT HUT ]
The wooden floor is scenery in scout hut.
The scout emblems are scenery in scout hut.
The posters are scenery in scout hut.
The walls are scenery in scout hut.
The cardboard box is a container in scout hut. The description is "The box contains [list of things in box]."
Some old books are a thing in the box. The description is "Extremely boring volumes with equally boring covers, all of which are very tatty and only suitable for a Jumble Sale."
Before taking the old books:
say "They're not important.";
stop the action.
The battered pan is a container in the box. The description is "Obviously had a great deal of usage by the Scouts during camping expeditions, but still capable of being used[if the baked beans are in the pan]. It contains some beans[end if]."
[ Default response - don't let the player put anything in the pan; it's too complex to deal with what might happen if they try to put the beans in there too! ]
Instead of inserting something into the battered pan:
say "I don't think that will help!".
[ RANGER'S HOUSE ]
The ranger-house-door is a private door. It is scenery. The printed name is "door". Understand "door" as the ranger-house-door. The ranger-house-door is closed. It is southeast of moor lane east and inside of moor lane east.
Opening the ranger-house-door is rudely invading.
Instead of knocking on ranger-house-door when the Ranger is in Ranger's house and the darkness index is 0:
say "After a while, you hear footsteps and the door opens. Crossly, the Ranger snaps 'Oh! The reporter! I'm sure I can't help, but you may as well come in!' before he unceremoniously ushers you in.";
move the player to Ranger's house.
The ranger-posters are scenery in Ranger's house. The printed name is "posters". Understand "posters" as the ranger-posters. The description is "Most depict scenes of local tourist spots, but one is about a hunting holiday, and another about a local hunt organized by the ranger."
The table is scenery in Ranger's house.
The guided tour notice is scenery in Ranger's house. The description is "Reads: [bold type]Guided tours £5[roman type]."
To say leaflet text:
say "Issued by the local Ranger, it waffles on about not straying onto the Moor unless properly attired in weather-proof kagoule and stout shoes, continuing to mention that a map is desirable, as well as it being advisable to take food supplies and a source of light etc. in case of accident, getting stranded in bad weather or the like"
[ "take leaflet" must work on the scenery item "leaflets" and leave the player with a single leaflet ]
The leaflets are scenery in Ranger's house. Understand "leaflet" as the leaflets. The description is "[leaflet text].".
The survival leaflet is a hidden object. The description is "[leaflet text].".
Instead of taking the leaflets:
if the survival leaflet is found begin;
say "But... you already have the survival leaflet.";
otherwise;
move the survival leaflet to the location;
try taking the survival leaflet;
end if.