The Beast of Torrack Moor
An interactive fiction by Linda Wright (2007) - the Inform 7 source text
Contents
Previous
Next
Complete text
Overgrown Garden is a windy room in Puddlecombe. "Weeds, especially nettles, thrust their way skywards on either side of a badly-cracked path which leads east to an ancient cottage, the one redeeming feature of this nearly derelict place being the ivy that creeps up the wall, almost hiding the door. A plaque peeps out from among the foliage and a large sign lies nearby."
The Living Room is a room in Puddlecombe. "You quickly appreciate Estate Agents[apostrophe] jargon for 'in need of some modernisation' as you stare at the peeling wallpaper, the crumbling ceiling and the rotten stairs, which look very unsafe. A doorway, having long since lost the door which presumably once fitted in it, leads south into the kitchen[if the ladder is propped up against the stairs]. You also observe a ladder propped up against the stairs[end if]."
The Kitchen is a room in Puddlecombe, south of Living Room. "Within this 'compact' room your outstretched arms conveniently touch the walls on either side, whilst through the grimy window of the back door you can just make out the back garden. The 'unit' consists of a couple of shelves, whilst under the sink there's a drawer with [if the broken handle is part of the kitchen-drawer]a broken[otherwise]no[end if] handle.".
The Back Garden is a room in Puddlecombe. "This small enclosed garden has tall weeds growing up through and between the paving slabs, whilst a pile of leaves has been blown into the corner, and a tumbledown outhouse stands to the south."
The Outhouse is a room in Puddlecombe, south of the Back Garden. "Rubble litters the floor of this tiny building which, going by the coaldust coating everything, was once used as a coalshed as well as being referred to in times past as 'the little room'."
The Bedroom is a room in Puddlecombe. "Like the rest of the cottage, the bedroom is in urgent need of decoration, with plaster falling from the ceiling and paint peeling off the woodwork, whilst the only exit is down the ladder to the living room below."
[ OVERGROWN GARDEN ]
Ivy Cottage is scenery in overgrown garden. Understand "house" as Ivy Cottage.
The weeds are scenery in overgrown garden. Understand "nettles" as the weeds.
The badly-cracked path is scenery in overgrown garden.
The foliage is scenery in overgrown garden.
The ivy is scenery in overgrown garden.
The ivy-cottage-door is a door and scenery. Understand "door" as ivy-cottage-door. The printed name is "door". It is closed and locked and lockable. It is east of overgrown garden and inside of overgrown garden and west of Living Room and outside of living room.
The yale key unlocks the ivy-cottage-door.
The ivy-cottage-plaque is scenery in overgrown garden. Understand "plaque" as ivy-cottage-plaque. The printed name is "plaque". The description is "Small, the words [bold type]IVY COTTAGE[roman type] are just legible under the grime."
The for sale sign is scenery in overgrown garden. The description is "It's a [bold type]FOR SALE[roman type] sign, and states [italic type]Contact Connum & Fleesum, High Street, Puddlecombe[roman type]."
A thing called a brick is in overgrown garden. The description is "Perfectly ordinary, with no outstanding qualities whatsoever."
[ LIVING ROOM ]
The peeling wallpaper is scenery in living room.
The crumbling ceiling is scenery in living room.
The rotten stairs are scenery in living room.
The doorway is scenery in living room.
[ The rucksack is a holdall - if the player carries too much, things will be put there. This is a marked improvement on the original game, which required a lot of object juggling! ]
A large rucksack is a container in the living room. Understand "backpack" and "sack" as the rucksack. The rucksack is wearable. The description is "Looking inside the rucksack you see [list of things in the rucksack]."
The rucksack is a player's holdall.
[ The ladder must be propped against the stairs to reach the bedroom ]
Instead of going up in living room:
if the ladder is propped up against the stairs,
send the player to bedroom;
otherwise
say "Aaargh! You try, but you lose your footing on the rotting boards and land safely, but ungainly, back on the floor.".
Instead of putting the ladder against the stairs when the ladder is normal:
now the ladder is part of the stairs;
now the ladder is propped up against the stairs;
say "OK, that's done.".
Instead of putting the ladder on the stairs:
try putting the ladder against the stairs.
[ Hint to the player that they won't need the ladder again... ]
Instead of taking the ladder when the ladder is propped up against the stairs:
say "No - that isn't necessary.".
Instead of climbing the ladder when the ladder is propped up against the stairs:
try going up.
[ KITCHEN ]
The grimy window is scenery in the kitchen.
A thing called the back garden is scenery in the kitchen.
The shelves are scenery in the kitchen. Understand "unit" as the shelves.
The sink is scenery in the kitchen.
The kitchen-drawer is an openable container in the kitchen. The printed name is "drawer". Understand "drawer" as the kitchen-drawer. The kitchen-drawer is scenery and closed. The description is "[if the kitchen-drawer is closed]Closed[otherwise]The drawer contains [a list of things in the kitchen-drawer][end if]."
The broken handle is part of the kitchen-drawer.
[ The player can only open the drawer if the hammer is carried. Opening it without the hammer causes the handle to fall off ]
Instead of opening the kitchen-drawer when the kitchen-drawer is closed:
if the broken handle is part of the kitchen-drawer begin;
say "You grab the handle and pull...and immediately the handle falls off, whilst the drawer remains closed!";
move the broken handle to the location.
otherwise if the hammer is carried;
try levering the kitchen-drawer with the hammer;
otherwise;
say "You try, but now that there is no handle attached, you fail miserably - perhaps if you had something to lever it open with?";
end if.
Instead of levering the kitchen-drawer with the hammer when the kitchen-drawer is closed:
say "Inserting the claw end of the hammer under the rim of the drawer, you eventually succeed in levering it open.";
now the kitchen-drawer is open;
record "levering open a tricky drawer" as achieved.
Instead of unlocking the kitchen-drawer with the hammer when the kitchen-drawer is closed:
try levering the kitchen-drawer with the hammer.
A tin opener is a thing in the kitchen-drawer. The description is "A useful implement."
[ This door is bolted rather than locked - no key is required ]
A door can be boltable or not boltable. A door is usually not boltable.
The back door is a private door. The back door is east of kitchen and outside of the kitchen and west of back garden and inside of back garden. The back door is boltable. It can be bolted or unbolted. The back door is closed, bolted and scenery. The description is "Lying to the east, it's [if the back door is bolted]bolted[otherwise]unbolted[end if].".
Instead of opening the back door when the back door is bolted:
say "You try, but it doesn't budge.".
Instead of bolting the back door:
if the back door is unbolted begin;
say "OK, that's done.";
now the back door is closed;
now the back door is bolted;
otherwise;
say "It's already bolted.";
end if.
Instead of unbolting the back door:
if the back door is bolted begin;
say "OK, that's done. The door swings open.";
now the back door is unbolted;
now the back door is open;
otherwise;
say "It's already unbolted.";
end if.
[ BACK GARDEN ]
The weeds are scenery in back garden.
The paving slabs are scenery in back garden.
The outhouse-object is scenery in back garden. Understand "outhouse" as the outhouse-object. The printed name is "outhouse".
[ The tortoise is hiding in the leaves. Every few moves, it rustles to hint to the player that it's there ]
The tortoise is a hidden object. The description is "Aaah! It's cute!".
The leaves are a hider. The leaves are scenery in back garden. The hidden of the leaves is the tortoise. The exclamation of the leaves is "Ah!". The takeflag of the leaves is 0.
Every turn in the back garden when the tortoise is not found:
if a random chance of 1 in 3 succeeds, say "The leaves rustle.".
The ladder is a thing in back garden. The description is "Long, and useful for climbing up (or down) when leant against a suitable wall, etc."
The ladder can be normal or propped up against the stairs. The ladder is normal.
[ OUTHOUSE ]
The rubble is scenery in the outhouse.
The coaldust is scenery in the outhouse. Understand "coal" and "dust" as the coaldust.
The small trowel is a thing in the outhouse. The description is "A useful implement.".
[ THE BEDROOM ]
The candle is a thing in the bedroom. The candle can be lit or unlit. The candle is unlit. Understand "wax" and "lit" and "unlit" as the candle. The printed name is "[if the candle is unlit]un[end if]lit candle". The description is "[if the candle is lit]The candle's giving off a small light, whilst the wax and wick are slowly disappearing[otherwise]Long and thin, it's made of white wax with a wick stuffed inside, and is usually used to provide a light when it gets dark[end if]."
The long wick is part of the candle. Understand "fuse" as the long wick. The description is "[if the long wick is not part of the candle]Waxed, it could be useful in a candle, or even as a fuse[otherwise]It's part of the candle[end if]."
Instead of taking the long wick when the long wick is part of the candle:
say "It's stuck in the candle."
Instead of pulling the long wick when the long wick is part of the candle:
try taking the long wick.
[ Useless vase ]
A blue vase is a thing in the bedroom. The description is "Large!"
The plaster is scenery in the bedroom.
The ceiling is scenery in the bedroom.
The paint and the woodwork are scenery in the bedroom.
Instead of going down in the bedroom:
send the player to living room.