The Beast of Torrack Moor
An interactive fiction by Linda Wright (2007) - the Inform 7 source text
Contents
Previous
Next
Complete text
The Farmyard is east of Moor Lane East. "A sign reading [italic type]PUBLIC FOOTPATH: TO THE MOOR[roman type] points east across this muddy cobbled yard, to the north of which lies an old stone farmhouse with a blue door, whilst a tatty barn lies to the northeast."
The Farm-building is a room.
The Barn is a room. The barn is northeast of the farmyard. "A barn is a barn is a barn, this one having the standard straw-covered floor, manure in the corner and a powerful pong to go with it."
The Field is east of the farmyard. "A rough track goes around this ploughed field to the southeast, where you can see another foot-path sign pointing towards the moors, whilst to the east there's a gap in the hedge."
The Meadow is east of the field. "This area of rough grassland is bordered by hedges to the west and south, through both of which is a small gap, whilst a near-vertical rocky slope prevents further progress to the east. The long grass sways wildly in the strong wind, and a barbed-wire fence blocks the way north. However, a rather strong smell like rotting meat spoils the otherwise pleasant atmosphere."
Rough Pasture is south of the meadow and southeast of the field. "A track from the neighbouring field becomes a narrow path which wends its way from the northwest corner to a gate on the easter edge, with a small gap in the hedge leading north to a meadow, whilst a steep ditch lies to the west and sheep graze peacefully on the short grass."
A Deep Ditch is west of Rough Pasture and below Rough Pasture. "Yuck! Squelchy mud and stagnant water fill this wonderful man made ditch, which only a fool or an idiot would remain in for long, and you quickly realise that the only exit is up."
[ BACKDROPS ]
The gap in the hedge is a backdrop. The gap in the hedge is in the field. The gap in the hedge is in the meadow. The gap in the hedge is in rough pasture.
The track is a backdrop. The track is in rough pasture.
[ FARM ]
The sign, the muddy cobbled yard, the old stone farmhouse are scenery in the farmyard.
The farm barn is scenery in the farmyard. The farm barn has printed name "barn".
The blue door is a private door and scenery in the farmyard. The blue door is north of the farmyard and south of the farm-building.
[ Here's the rudely invading rule - it's used for most of the doors to the houses ]
Opening the blue door is rudely invading.
Instead of rudely invading:
say "Really! Do you always barge into other people's homes like this? Honestly, some adventurers have terrible manners!"
The straw covered floor and manure is scenery in the barn.
[ FARMER LAMB ]
Farmer Lamb is a villager man in the Farmyard. "Farmer Lamb is here, with a worried expression on his face." The description is "Well-built, tanned and healthy." The default answer of Farmer Lamb is "I'm afraid he's too deep in thought to answer!"
Farmer lamb has a room called the destination.
[ Farmer Lamb has several modes. Generally he wanders aimlessly around the farm. If you tell him about the dead sheep, he'll go to get it, take it back to the barn, and then wander off again. ]
Farmer Lamb is either idle, wandering, fetching the dead sheep, taking the dead sheep to the barn, going home or at home. Farmer Lamb is idle.
The large key is a key.
[ Nudging Farmer Lamb makes him act appropriately. I haven't used the automatic route-finding code because I found it was quite slow on my (slow) computer. ]
To nudge farmer lamb:
if Farmer Lamb is wandering begin;
let x be a random number between 1 and 6;
if Farmer Lamb is in the Barn begin;
let right direction be southwest;
otherwise if Farmer Lamb is in the Farmyard;
if x is greater than 3,
let right direction be northeast;
otherwise
let right direction be east;
otherwise if Farmer Lamb is in the Field;
if x is greater than 4 begin;
let right direction be west;
otherwise if x is greater than 2;
let right direction be east;
otherwise;
let right direction be southeast;
end if;
otherwise if Farmer Lamb is in the Meadow;
if x is greater than 3,
let right direction be west;
otherwise
let right direction be south;
otherwise if Farmer Lamb is in Rough Pasture;
if x is greater than 3,
let right direction be northwest;
otherwise
let right direction be north;
end if;
send farmer Lamb to the right direction with "default";
now Farmer Lamb is idle;
otherwise if Farmer Lamb is not idle;
if Farmer Lamb is not in the destination of Farmer Lamb begin;
let the right direction be the best route from the location of Farmer Lamb to the destination of Farmer Lamb;
send Farmer Lamb to the right direction with "default";
end if;
if Farmer Lamb is in the destination of Farmer Lamb begin;
if Farmer Lamb is fetching the dead sheep begin;
remove the dead sheep from play;
now Farmer Lamb is taking the dead sheep to the barn;
now the destination of Farmer Lamb is the barn;
otherwise if Farmer Lamb is taking the dead sheep to the barn;
move the dead sheep to barn;
now Farmer Lamb is idle;
otherwise if Farmer Lamb is going home;
now Farmer Lamb is at home;
send Farmer Lamb inside from the Farmyard to the Farm-building;
end if;
end if;
end if.
[ Every so often, nudge Farmer Lamb and make him do stuff ]
Every turn when Farmer Lamb is not at home:
if Farmer Lamb is idle and a random chance of 1 in 8 succeeds begin;
now Farmer Lamb is wandering;
choose a random row in the Table of Farm Locations;
change the destination of Farmer Lamb to the room entry;
end if;
if Farmer Lamb is not idle,
nudge Farmer Lamb.
Table of Farm Locations
| room |
| Farmyard |
| Field |
| Barn |
| Meadow |
| Rough Pasture |
Instead of informing farmer lamb about the dead sheep:
if the dead sheep is found and the large key is not found begin;
say "'A dead sheep, you say?' mutters the farmer. 'Bet it was got at by that beast, then. Here, if you be going on Moor to track that creature down, you best be having this... it's the key to the old shepherd's hut, down by river, then if weather turns bad, you can shelter there for night. I'd best be going off to look at the sheep... best of luck, young'un!' And with that, he wanders off.";
now the large key is found;
move the large key to the location;
try taking the large key;
record "obtaining the key to the shepherd's hut" as achieved;
now farmer lamb is fetching the dead sheep;
change the destination of farmer lamb to the meadow;
end if.
[ BARN ]
Instead of exiting in the barn:
try going southwest.
[ FIELD ]
The rough track is scenery in the field.
Torrack Moor is a backdrop. Torrack Moor is in the field. Understand "moors" as Torrack Moor.
The footpath sign is scenery in the field.
[ ROUGH PASTURE ]
The steep ditch is scenery in rough pasture.
The sheep are scenery in rough pasture. The description is "Very ordinary!"
The meadow from a distance is scenery in rough pasture. The printed name of the meadow-item is "meadow".
The short grass is scenery in rough pasture.
The rough-pasture-gate is a private door. It is scenery. The printed name is "gate". Understand "gate" as the rough-pasture-gate. The rough-pasture-gate is east of rough pasture and west of steep path. The rough-pasture-gate is closed.
Instead of going east when in rough pasture:
try opening the rough-pasture-gate.
Instead of opening the rough-pasture-gate:
say "Unfortunately, the gate is firmly chained to a metal gatepost, and can't be opened.".
Instead of climbing the rough-pasture-gate:
if the player is in rough pasture,
send the player to steep path;
otherwise
send the player to rough pasture;
change the sogginess index to 0.
[ THE MEADOW ]
The hedges are scenery in the meadow.
The rocky slope is scenery in the meadow.
[ The barbed wire fence conceals some black fur ]
Some black fur is a hidden object. It is pocketable. The description is "Looks like cat's fur."
The barbed-wire fence is scenery in the meadow. The barbed-wire fence is a hider. The hidden of the barbed-wire fence is some black fur. The exclamation of the barbed-wire fence is "Ooh!". The scorename of the barbed-wire fence is "finding some black fur".
[ The long grass conceals a dead sheep ]
A dead sheep is a hidden object. The dead sheep is known and not portable. The description is "Badly mauled and half eaten. Ugh!"
The long grass is scenery in the meadow. The long grass is a hider. The hidden of the long grass is a dead sheep. The exclamation of the long grass is "Ah!".
[ A DEEP DITCH ]
The bird watcher is a man in the deep ditch. Understand "man" as bird watcher. Understand "birdwatcher" as the bird watcher. Understand "twitcher" as the bird watcher. "You notice a man lying on the bank, groaning." The description is "Going by his green coat, green hat and the bird emblem on it, I would say that he's a typical twitcher!" The default answer of the bird watcher is "He just groans."
Instead of talking to the bird watcher for the first time:
say "Groaning, he rubs his leg, then moans, 'I think it's broken! Get me a doctor!' then relates his tale of how he was trying to take a photo of a rare lesser spotted red-billed woodpecker when he fell... the bird, of course, flew away!"
Instead of asking the bird watcher what's wrong:
try talking to the bird watcher.
Instead of asking the bird watcher about something:
try talking to the bird watcher.
Instead of interrogating the bird watcher about something:
try talking to the bird watcher.
The camera is a container. The description is "A good, 35mm-job, with auto-focus, auto-lightmeter, long lens, etc - just the sort of thing for a lousy photographer like you!"
Instead of inserting something into the camera:
if the noun is the film begin;
move the film to the camera;
say "OK, that's done.";
otherwise;
say "That doesn't fit!";
end if.
Instead of exiting in deep ditch:
try going up.