The Beast of Torrack Moor
An interactive fiction by Linda Wright (2007) - the Inform 7 source text
Contents
Previous
Next
Complete text
Myrtlemove is a text that varies. Myrtlemove is "Miss Myrtle leaves.".
To send Miss Myrtle outside from (building - a room) to (outdoors - a room):
move Miss Myrtle to outdoors;
if the location is outdoors begin;
say "Suddenly, the door opens and Miss Myrtle appears before locking the door behind her.";
end if;
if the location is building begin;
say "Suddenly, Miss Myrtle says 'Oh! Is that the time already? I must be going... sorry, but you'll have to leave too!' and she bustles you outside as she puts on her hat and coat before leaving herself.";
move the player to outdoors;
end if.
To send Farmer Lamb inside from (outdoors - a room) to (building - a room):
move Farmer Lamb to building;
if the location is outdoors begin;
say "Farmer Lamb enters the Farm and closes the door behind him.";
end if.
To send Miss Myrtle inside from (outdoors - a room) to (building - a room):
move Miss Myrtle to building;
if the location is outdoors begin;
say "Fumbling in her bag, Miss Myrtle digs out a key, unlocks the door and goes in.";
end if.
Ermonmove is a text that varies. Ermonmove is "With a brief nod, the Reverend Ermon departs.".
To send the Reverend outside from (building - a room) to (outdoors - a room):
move the Reverend to outdoors;
if the location is outdoors begin;
say "Mumbling 'Oh hello...sorry can't stay,' the Reverend Ermon emerges from the house, shutting the door behind him.";
end if;
if the location is building begin;
say "Muttering 'Oh Lawd, is that the time?' he pushes you out of the door and follows, apologising as he explains that he must go out.";
move the player to outdoors;
end if.
To send the Reverend inside from (outdoors - a room) to (building - a room):
move the Reverend to building;
if the location is outdoors begin;
say "Mumbling 'Ah, hello, nice to see you!' the Reverend unlocks the door and goes in.";
end if.
To send the mobile library to (destination - a room):
move the mobile library to destination;
if the location is destination begin;
if the location is the Green,
say "A mobile library has arrived, and, after a little manoeuvring, it is parked to the east of the Green before the doors are opened.";
otherwise
say "A mobile library wends its way through the traffic.";
end if.
At 10:57 AM:
[ Mobile library enters road-room ]
send the mobile library to road-room.
At 10:58 AM:
[ Mobile library enters high street west ]
send the mobile library to High Street West.
At 10:59 AM:
[ Mobile library enters high street east ]
send the mobile library to High Street East.
At 11 AM:
[ Open the pub door ]
now the thick wooden door is unlocked;
now the thick wooden door is open;
if the player is in Outside-Pub,
say "The pub door is opened.";
[ Mobile library arrives ]
send the mobile library to the Green;
send the Ranger to the north with "The Ranger wanders north into the pub.".
At 11:05 AM:
[ Miss Myrtle leaves cottage ]
send Miss Myrtle outside from Myrtle Cottage to Pretty Garden.
At 11:06 AM:
[ Myrtle: pretty garden -> church lane ]
send Miss Myrtle to the north with myrtlemove.
At 11:07 AM:
[ Myrtle: church lane -> green ]
send Miss Myrtle to the northwest with myrtlemove.
At 11:08 AM:
[ Myrtle: green -> library ]
send Miss Myrtle to the east with myrtlemove.
At 11:27 AM:
[ Myrtle: library -> green ]
send Miss Myrtle to the west with myrtlemove.
At 11:28 AM:
[ Myrtle: green -> church lane ]
send Miss Myrtle to the southeast with myrtlemove.
At 11:29 AM:
[ Myrtle: church lane -> outside the church ]
send Miss Myrtle to the southeast with myrtlemove.
At 11:30 AM:
[ Myrtle: outside the church -> church porch ]
send Miss Myrtle to the south with myrtlemove;
[ Tea shop opens ]
now the tea-shop-door is unlocked;
now the tea-shop-door is open.
At 11:31 AM:
[ Myrtle: church porch -> church ]
send Miss Myrtle inside from church porch to church nave;
now the large wooden door is unlocked;
now the large wooden door is open.
At 12:00 PM:
now the current day is evening;
[ Reverend: vicarage -> vicarage garden ]
send the Reverend outside from vicarage to vicarage garden;
[ Ranger: leaves pub ]
send the Ranger to the south with "default".
At 12:01 PM:
[ Reverend: vicarage garden -> church lane ]
send the Reverend to the northeast with ermonmove.
At 12:02 PM:
[ Reverend: church lane -> green ]
send the Reverend to the northwest with ermonmove.
At 12:03 PM:
[ Reverend: green -> high street east ]
send the Reverend to the west with ermonmove.
At 12:04 PM:
[ Reverend: high street east-> stores ]
send the Reverend to the south with ermonmove.
At 12:05 PM:
[ Ranger: outside pub -> green ]
send the Ranger to the south with "default".
At 12:06 PM:
[ Ranger: green -> moor lane west ]
send the Ranger to the northeast with "default".
At 12:07 PM:
[ Ranger: moor lane west -> moor lane east ]
send the Ranger to the east with "default".
At 12:07 PM:
[ Ranger: moor lane west -> moor lane east ]
move the Ranger to ranger's house;
if the location is moor lane east,
say "The Ranger unlocks the door of his house and goes in.".
At 12:19 PM:
[ Reverend: stores-> high street east ]
send the Reverend to the north with ermonmove.
At 12:20 PM:
[ Reverend: high street east-> green ]
send the Reverend to the east with ermonmove.
At 12:21 PM:
[ Reverend: green-> library ]
send the Reverend to the east with ermonmove.
At 12:39 PM:
[ Reverend: library-> green ]
send the Reverend to the west with ermonmove.
At 12:40 PM:
[ Myrtle: church -> church porch]
[ FIXME: what happens if the player is in the chancel? ]
send Miss Myrtle outside from Church Nave to Church Porch;
now the large wooden door is closed;
now the large wooden door is locked;
[ Reverend: green -> church lane ]
send the Reverend to the southeast with ermonmove.
At 12:41 PM:
[ Myrtle: church porch -> outside the church ]
send Miss Myrtle to the north with myrtlemove;
[ Reverend: church lane -> vicarage garden ]
send the Reverend to the southwest with ermonmove.
At 12:42 PM:
[ Myrtle: outside the church -> church lane]
send Miss Myrtle to the northwest with myrtlemove;
[ Reverend: vicarage garden -> vicarage ]
send the Reverend inside from vicarage garden to vicarage.
At 12:43 PM:
[ Myrtle: church lane -> pretty garden ]
send Miss Myrtle to the south with myrtlemove.
At 12:44 PM:
[ Myrtle: church lane -> pretty garden ]
send Miss Myrtle to the south with myrtlemove.
At 12:45 PM:
[ Murtle: pretty garden -> myrtle cottage ]
send Miss Myrtle inside from pretty garden to myrtle cottage.
At 12:59 PM:
[ Library closes ]
if the location is the library-room begin;
say "Miss Kriett suddenly announces that the library is now closed, and evicts you.";
move the player to the green;
now the mobile library is closed;
end if;
[ Stores closes for lunch ]
if the location is the stores begin;
say "Lily White announces that she is closing for lunch, and ushers you out.";
move the player to high street east;
end if;
now the door of the stores is closed;
now the door of the stores is locked.
At 1:05 PM:
[ Library drives away ]
if the location is the green,
say "The library is driven away.";
move the mobile library to High Street East.
At 1:06 PM:
[ Library: high street east -> west ]
move the mobile library to High Street West;
At 1:07 PM:
[ Library: drives off ]
remove the mobile library from play.
At 1:56 PM:
[ Miss Myrtle leaves cottage again ]
send Miss Myrtle outside from Myrtle Cottage to Pretty Garden.
At 1:57 PM:
[ Myrtle: pretty garden -> church lane ]
send Miss Myrtle to the north with myrtlemove.
At 1:58 PM:
[ Myrtle: church lane -> church hall ]
send Miss Myrtle inside from church lane to church hall;
now the church hall door is unlocked;
now the church hall door is closed.
At 2 PM:
[ Church hall door opens ]
if the player is in church lane and the church hall door is closed,
say "The door of the hall has just opened.";
now the church hall door is unlocked;
now the church hall door is open;
[ Reverend: Vicarage -> attractive garden ]
send the Reverend outside from Vicarage to vicarage garden.
[ Stores opens after lunch ]
now the door of the stores is unlocked;
now the door of the stores is open.
At 2:01 PM:
[ Reverend: attractive garden -> church lane ]
send the Reverend to the northeast with ermonmove.
At 2:02 PM:
[ Reverend: church lane -> church hall ]
send the Reverend to the east with ermonmove.
At 3 PM:
[ Reverend: church hall -> church lane ]
send the Reverend to the west with ermonmove.
At 3:01 PM:
[ Reverend: church lane -> green ]
send the Reverend to the northwest with ermonmove.
At 3:25 PM:
[ Jumble sale over ]
now the Church Hall door is closed;
now the Church Hall door is locked;
if the player is in the Church Hall begin;
say "The Jumble Sale is now over and Miss Myrtle gently pushes you out before closing the door behind her.";
move the player to Church Lane;
move Miss Myrtle to Church Lane;
otherwise;
send Miss Myrtle outside from Church Hall to Church Lane;
end if;
now Miss Myrtle is seeking a raffle winner.
At 3:26 PM:
[ Miss Myrtle: church lane -> green ]
send Miss Myrtle to the northwest with myrtlemove.
At 3:27 PM:
if Miss Myrtle is seeking a raffle winner,
now the notice-board is amended;
[ Myrtle: green -> high street east ]
send Miss Myrtle to the west with myrtlemove.
At 3:28 PM:
[ Myrtle: high street east -> stores ]
send Miss Myrtle to the south with myrtlemove.
At 3:30 PM:
[ Myrtle: stores -> high street east ]
send Miss Myrtle to the north with myrtlemove.
At 3:31 PM:
[ Myrtle: high street east -> green ]
send Miss Myrtle to the north with myrtlemove;
[ Reverend: green -> church lane ]
send the Reverend to the southeast with ermonmove.
At 3:32 PM:
[ Reverend: church lane -> vicarage garden ]
send the Reverend to the southwest with ermonmove.
At 3:33 PM:
[ Reverend: vicarage garden -> vicarage ]
send the Reverend inside from vicarage garden to vicarage.
At 3:36 PM:
[ Miss Myrtle: green -> church lane ]
send Miss Myrtle to the southeast with myrtlemove.
At 3:55 PM:
[ Myrtle: Church Hall -> church lane ]
send Miss Myrtle outside from church hall to church lane.
At 4:15 PM:
[ Myrtle: church lane -> pretty garden ]
send Miss Myrtle to the south with myrtlemove.
At 4:16 PM:
[ Myrtle: church lane -> pretty garden ]
send Miss Myrtle inside from pretty garden to myrtle cottage.
At 5 PM:
[ Vet's closes ]
if the player is in vet's waiting room begin;
say "The receptionist announces that it is closing time, and ushers you out the door.";
move the player to high street west;
end if;
now the door of the stone building is closed;
now the door of the stone building is locked;
[ Estate agents closes ]
if the player is in estate agents begin;
say "The estate agent announces that it is closing time, and ushers you out the door.";
move the player to high street east;
end if;
now the door of the estate agents is closed;
now the door of the estate agents is locked.
[ Stores closes ]
if the player is in stores begin;
say "Lily White announces that it is closing time, and ushers you out the door.";
move the player to high street east;
end if;
now the door of the stores is closed;
now the door of the stores is locked.
At 6 PM:
[ Tea shoppe closes ]
if the player is in tea shoppe begin;
say "The waitress announces that it is closing time, and ushers you out the door.";
move the player to the green;
end if;
now the tea-shop-door is closed;
now the tea-shop-door is locked.
To say time-to-leave:
say "It's getting dark outside. Deciding that you'll achieve nothing here, you say goodbye and leave.".
To announce darkness with (message - a text):
if the player is not carrying the torch or the torch is unlit begin;
if the player is not in the shepherd's hut or the shepherds-fire is not in the shepherds-fireplace,
say message;
end if.
At 6:40 PM:
[ Doctor leaves conservatory? ]
remove the doctor from play;
[ Leave various cottages ]
if the player is in Myrtle Cottage begin;
say time-to-leave;
move the player to pretty garden;
otherwise if player is in Vicarage;
say time-to-leave;
move the player to vicarage garden;
otherwise if player is in Ranger's House;
say time-to-leave;
move the player to Moor Lane East;
otherwise;
say "It's getting dark.";
end if;
change darkness index to 1;
change the destination of Farmer Lamb to the farmyard;
now Farmer Lamb is going home.
At 6:55 PM:
announce darkness with "You can hardly see.".
At 7:15 PM:
announce darkness with "You can hardly see.".
At 7:30 PM:
announce darkness with "It's becoming very difficult to see...".
At 7:35 PM:
now everywhere is dark;
change darkness index to 2.
At 11:00 PM:
[ Pub closes ]
if the player is in the pub begin;
say "The publican announces that it is closing time, and ushers you out the door.";
move the player to outside-pub;
end if;
now the thick wooden door is closed;
now the thick wooden door is locked.