The Beast of Torrack Moor
An interactive fiction by Linda Wright (2007) - the Inform 7 source text
Contents
Previous
Next
Complete text
[ The "known" property is used to identify objects that can be ASKed ABOUT ]
A thing can be known or unknown. A thing is usually unknown.
A person is usually known.
[ There's a stock set of responses to certain questions, but they don't apply to the editor ]
A person can be villager or not villager. A person is usually not villager.
A person has a text called the default answer.
To say the default response of (respondee - a person):
say the default answer of the noun;
say "[line break]".
[ default response to ask/tell ]
This is the default response rule:
say the default response of the noun.
The default response rule is listed instead of the block asking rule in the report asking it about rules.
The default response rule is listed instead of the block telling rule in the report telling it about rules.
[ Abstract things to ask about ]
The beast is a known thing.
Torrack Moor is a known thing.
The jumble sale is a known thing.
The quarry is a known thing.
The Vet is a known villager man.
The guided tour is a known thing.
The doctor is a known man. The printed name is "the doctor". The doctor is proper-named. Understand "Sawly" as the doctor.
The camera is a known thing.
Eldritch Combe is a known thing.
The weather forecast is a known thing.
The church is a known thing.
The church-key is a known thing. Understand "key" as the church-key.
Flowers are a known thing.
[ Ensure that asking about the church doesn't ask whether the player means the church key ]
Does the player mean interrogating someone about the church: it is likely.
[ Table of responses to ask ]
Instead of interrogating a villager person about something:
[ If we're asking about a person, check if they're around first! This also
deals with asking people about themselves. ]
if the second noun is a person and the location of the second noun is the location of the noun begin;
say the default response of the noun;
otherwise;
[ Check to see if we have a specific response for this question ]
repeat through the Table of Specific Responses begin;
if the noun is respondent entry and the second noun is item entry begin;
say "[reply entry][paragraph break]";
rule succeeds;
end if;
end repeat;
[ Now check if there's a default response ]
if the second noun is an item listed in the Table of Default Responses begin;
say "[reply entry][paragraph break]";
rule succeeds;
end if;
[ Ottherwise, give default response ]
say the default response of the noun;
end if.
Table of Specific Responses
| respondent | item | reply |
| Ranger | beast | "Looking down his nose at you, the Ranger growls 'Like I said, a load of waffle! No such thing! Just a large fox, I say!'" |
| Ranger | Farmer Lamb | "Snorting 'Him!', Ernest stares at you so hard that you're left in no doubt that the doesn't much like Farmer Lamb!" |
| Ranger | Torrack Moor | "Warming slightly to the subject of his liking, the Ranger says: 'A dangerous place for town dwellers, you know! Not the area to be if you don't know your way around... splendid walking country in the summer, mind! Tourists love it... but I insist they're properly dressed and sometimes I act as a guide.' He pauses momentarily before adding, 'But only if I like them!' as he glowers at you." |
| Ranger | guided tour | "With a contemptible growl, he snorts 'No! No way!' and looks away." |
| Miss Myrtle | beast | "Eagerly, Rose replies 'I've seen it, you know, since I wrote that letter... A big, black animal it is, very fast. Saw it at dusk yesterday, near the farm... gave me quite a shock, it did, as it jumped over a gate... magnificent looking beast, mind. Went flying through the air then raced up the hill towards the Moor... the vet reckons it could be a wild cat of some sort. Only got a glimpse myself, mind.'" |
| Miss Myrtle | church | "She smiles and says, 'A lovely place. I arrange the flowers there, you know.'" |
| Miss Myrtle | flowers | "'I LOVE flowers,' enthuses Miss Myrtle. 'I do the arrangements in the church, you know... go in about noon most days.'" |
| Miss Myrtle | church-key | "Shaking her head, she murmurs 'I can't let you have the key - it's not mine, you see! People often come in, though when I'm in the church... but they have to go when I lock up. Great pity, it is... never used to have to lock churches but what with vandals and the like...' and then rambles on about the good old days." |
| Farmer Lamb | beast | "'Ah! The beast! Saw it t'other morning, early it was, just afore dawn. A black creature, stalking through long grass on the rough pasture, givin[apostrophe] sheep a real fright, I tell you!' mumbles the farmer, as he scratches his chin thoughtfully. 'Well, I shouted at it, I did, half expected it to turn on me but no... just turned tail and streaked off... leapt the gate and headed for Moor. Well, I told Ranger, but he were no darn use... told me I were going daft in my old age! But I'm not... that beast were real, alright! And it had one of my ewes t'other night, that I do know! You ask the Vet...he'll tell you!'" |
| Publican | Torrack Moor | "With a smile, George replies: 'I love the Moor... great place for walks, but the weather can be pretty grotty. There are some ancient standing stones that are worth a look, if you like that sort of thing, and the waterfall down in the valley is a real spectacle, especially when the river's in flood. Used to be a bridge, but it was destroyed in the flash floods last month... shame, [apostrophe]cos there's no way across now when the river's high - too deep to ford, you see.'" |
| Vet | beast | "'Ah, the Beast,' replies the vet. 'If you ask me, it's a large cat of some kind, possibly a panther, though how it got onto the Moor is anyone's guess - probably escaped from a small zoo or something like that.'" |
| Vet | painting of panthers | "Smiling, the vet says 'Lovely picture, that! Fantastic animals, big cats. They can travel miles, you know, though they mostly hunt at night. Best time to see them in the wild is at dusk or dawn... saw some leopards once, on safari. Beautiful creatures! Came down to the water to drink at dawn. We were well hidden on a nearby ledge, so had a marvellous view. Great climbers, they are, very difficult to spot normally as they're quite shy, so we were lucky.'" |
| Vet | dead sheep | "Frowning, the vet answers, 'I can tell you this - that sheep of Farmer Lamb's wasn't killed by a fox. More likely by a wild cat of some kind, going by the way the throat was torn.'" |
Table of Default Responses
| item | reply |
| beast | "With a shake of the head, the reply 'The beast! That's a real mystery! Never seen it myself, although I've heard that it's like a large black cat, and Farmer Lamb reckons he saw it the other day...' is all you get." |
| Torrack Moor | "Saying 'Ah! The Moor! Nice place for rambling, if you're geared up for it, though the weather can often turn nasty up there!' before the speaker frowns and warns, 'Keep away from Eldritch Combe, mind! And don't cross the river if it's flooded... someone drowned there last month!'" |
| jumble sale | "'The Jumble Sale? Oh yes, it's at 2pm today, at the Church Hall, I think,' is the reply." |
| quarry | "'With a shrug, you're told 'The quarry? Hasn't been used for years.'" |
| Miss Myrtle | "'Ah! Miss Myrtle! A lovely old lady... very helpful, always busy, she is,' is the reply, with 'Lives in Church Lane, y'know.' added on for good measure." |
| Reverend | "With a slight nod, you're told that the Reverend's 'a good man, though he's rather scatter-brained at times...'" |
| Farmer Lamb | "'Farmer Lamb? Oh, he's OK, always worrying about the weather or something, but a decent chap, and not the sort to make up tales. Doesn't like the Ranger, though. But then, not many people do!' is the reply." |
| Ranger | "'Oh, him! A right pain in the neck, he is! Always looking to make a buck or two, from the tourists, that is. Wouldn't do him any good if the story of the Beast was known, mind. He thinks it might scare people off the Moor, and then he wouldn't make so much money, of course. Only took the job on cos he's useless at everything else!' is the reply." |
| Vet | "'Oh, he's a good vet!' you're told. 'What he doesn't know about animals isn't worth knowing!'" |
| Doctor | "With a smile, you're told 'He's a good doctor, but as deaf as a post! Lives in Moor Lane, and loves his garden; spends all his spare time tending his planes. Ah yes, a real character!'" |
| Eldritch Combe | "With a frown, you're told that some combes, like Eldritch Combe, are rarely visited because 'they be places of the devil and strange goings on...'" |
| weather forecast | "'Forecast's not good! Rain, high winds... should be better tomorrow, mind!' ends the talker, hopefully." |